home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / dsp / dr.bub / 96000.lha / 96000 / appb / b116.asm < prev    next >
Assembly Source File  |  1992-04-28  |  6KB  |  155 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.16    LMS ADAPTIVE FILTER  
  8. ;l      
  9. ;Notation and symbols: 
  10. ;;  x(n)  - Input sample at time n. 
  11. ;  d(n)  - Desired signal at time n. 
  12. ;  f(n)  - FIR filter output at time n. 
  13. ;  H(n)  - Filter coefficient vector at time n.    H={h0,h1,h2,h3} 
  14. ;  X(n)  - Filter state variable vector at time n. X={x0,x1,x2,x3} 
  15. ;  u     - Adaptation gain. 
  16. ;  ntaps - Number of coefficient taps in the filter. For this 
  17. ;          example, ntaps=4. 
  18. ; 
  19. ; Exact LMS Algorithm: 
  20. ; e(n)=d(n)-H(n)X(n)    (FIR filter and error) 
  21. ; H(n+1)=H(n)+uX(n)e(n) (Coefficient update) 
  22. ; 
  23. ; Delayed LMS Algorithm: 
  24. ; e(n)=d(n)-H(n)X(n)        (FIR filter and error) 
  25. ; H(n+1)=H(n)+uX(n-1)e(n-1) (Coefficient update) 
  26.  
  27. ;In the exact LMS algorithm, the output of the FIR filter is first  calculated (f(n)) and then the coeffi-
  28. ;cients are updated using the  current error signal and coefficients.  In the delayed LMS algorithm,  
  29. ;the FIR filter and coefficient update is performed at the same time. The  coefficients are updated with 
  30. ;the error value and coefficients from the  previous sample.  
  31. ;References: 
  32. ;  "Adaptive Digital Filters and Signal Analysis", Maurice G. Bellanger 
  33. ;      Marcel Dekker, Inc. New York and Basel 
  34. ; 
  35. ;  "The DLMS Algorithm Suitable for the Pipelined Realization of Adaptive 
  36. ;      Filters", Proc. IEEE ASSP Workshop, Academia Sinica, Beijing, 1986 
  37. ;
  38. ;The sections of code shown describe how to initialize all registers,  filter an input sample and do the 
  39. ;coefficient update.  Only the  instructions relating to the filtering and coefficient update are shown  as 
  40. ;part of the benchmark.  Instructions executed only once (for  initialization) or instructions that may 
  41. ;be user application dependent  are not included in the benchmark.  
  42. ;                                                    Exact LMS Algorithm 
  43. ; 
  44. ntaps    equ     4 
  45. u        equ     .01 
  46.  
  47.          org     x:0 
  48. sbuf     ds      ntaps 
  49.  
  50.          org     y:0 
  51. cbuf     ds      ntaps 
  52.  
  53.          org     y:10 
  54. dsig     ds      1 
  55. xsig     ds      1 
  56.  
  57.          org     p:$50 
  58. start 
  59.   move      #sbuf,r0            ;point to state buffer 
  60.   move      #cbuf,r4            ;point to coefficient buffer 
  61.   move      r4,r5               ;extra pointer 
  62.   move      #ntaps-1,m0         ;mod on pointers 
  63.   move      #ntaps-1,m4 
  64.   move      #ntaps-1,m5 
  65.   move      #-3,n0              ;final adjustment 
  66.   move      #u,d7.s             ;adaptation constant 
  67.  
  68. main 
  69.   fclr    d1                            y:xsig,d4.s 
  70.   fclr    d0            d4.s,x:(r0)+    y:(r4)+,d5.s 
  71.   rep     #ntaps 
  72.   fmpy    d4,d5,d1  fadd.s d1,d0  x:(r0)+,d4.s  y:(r4)+,d5.s 
  73.   fadd.s  d1,d0         x:(r0)-,d4.s    y:(r4)-,d5.s 
  74.  
  75.   move                                  y:dsig,d1.s 
  76.   fsub.s  d0,d1 
  77.   fmpy.s  d7,d1,d1      x:(r0)+,d4.s 
  78.  
  79.   fmpy.s  d4,d1,d3                      y:(r4)+,d5.s 
  80.   fadd.s  d3,d5         x:(r0)+,d4.s 
  81.   do      #ntaps,cup 
  82.   fmpy.s  d4,d1,d3      d5.s,d0.s       y:(r4)+,d5.s 
  83.   fadd.s  d3,d5         x:(r0)+,d4.s    d0.s,y:(r5)+ 
  84. cup 
  85.   move                  x:(r0)+n0,d4.s  y:(r4)-,d0.s 
  86.   jmp     main 
  87.   end 
  88.  
  89. ;The FIR filter requires 1N/coefficient and the coefficient update  requires 2N/coefficient for a total of 
  90. ;3N/coefficient.  
  91. ;On the delayed LMS algorithm, the coefficients are updated with the  error from the previous itera-
  92. ;tion while the FIR filter is being computed  for the current iteration.  In the following implementation, 
  93. ;two  coefficients are updated with each pass of the loop.  
  94. ;                                            Delayed LMS Algorithm 
  95.  
  96. iter      equ   50              ;Number of LMS iterations 
  97. conv_fact equ   0.01            ;Convergence factor 
  98.  
  99.           org   x:$0 
  100. state     ds    11              ;State of lms fir 
  101.  
  102.           org   y:$0 
  103. coef      ds    10              ;LMS coefficients 
  104.  
  105. e         dc    0.0             ;Signal error 
  106. xin       ds    1               ;Input to system 
  107. dsig      ds    1               ;Desired signal 
  108.  
  109.           org   p:$100 
  110. lmstest 
  111.   move   #state,r0          ;Set up address generators 
  112.   move   #10,m0 
  113.   move   #xstate,r1 
  114.   move   #9,m1 
  115.   move   #coef,r4 
  116.   move   #9,m4 
  117.   move   #coef,r5 
  118.   move   #9,m5 
  119.   move   #xcoef,r6 
  120.   move   #9,m6 
  121.  
  122.   move   #iter,d0.l 
  123.   do     d0.l,lms 
  124.   ; LMS algorithm setup 
  125.   move                                         y:e,d0.s 
  126.   move                           #conv_fact,d1.s 
  127.   fmpy.s d0,d1,d0                              y:xin,d6.s 
  128.   move                           d0.s,d9.s 
  129.   move                           d6.s,x:(r0) 
  130.   ; LMS algorithm loop 
  131.   move                           x:(r0)+,d6.s  y:(r4)+,d7.s 
  132.   fmpy.s d7,d6,d1                x:(r0)+,d4.s  y:(r4)+,d5.s 
  133.   fmpy.s d9,d4,d2 
  134.   fmpy   d5,d4,d0  fadd.s d7,d2  x:(r0)+,d6.s 
  135.   do #4,_lms_loop 
  136.   fmpy   d9,d6,d3  fadd.s d0,d1                y:(r4)+,d7.s 
  137.   fmpy   d7,d6,d0  fadd.s d5,d3  x:(r0)+,d4.s  d2.s,y:(r5)+ 
  138.   fmpy   d9,d4,d2  fadd.s d0,d1                y:(r4)+,d5.s 
  139.   fmpy   d5,d4,d0  fadd.s d7,d2  x:(r0)+,d6.s  d3.s,y:(r5)+ 
  140. _lms_loop 
  141.  
  142.   fmpy   d9,d6,d3  fadd.s d0,d1                d2.s,y:(r5)+ 
  143.                    fadd.s d5,d3  (r0)- 
  144.   move                                         d3.s,y:(r5)+ 
  145.   move                                         y:dsig,d2.s 
  146.   fsub.s                         d1,d2 
  147.   move                                         d2.s,y:e 
  148. lms 
  149.   nop 
  150.   nop 
  151.   end 
  152.  
  153. ;The inner loop updates the coefficients and performs the FIR filtering  for a speed of 2N per coeffi-
  154. ;cient.  
  155.